Excel VBA データを集計して集計シートに集計データ抽出する

Sub 抽出()
Application.ScreenUpdating = False
　With Range("A1").CurrentRegion
　　　.Sort key1:=.Columns(2), order1:=xlAscending, Header:=xlYes
　　　.Subtotal GroupBy:=2, Function:=xlSum, TotalList:=Array(3), _
　　　　Replace:=True, PageBreaks:=False, SummaryBelowData:=True
　End With
　　　ActiveSheet.Outline.ShowLevels RowLevels:=2
　　　Range("A1").CurrentRegion.SpecialCells(xlCellTypeVisible).Copy
　　　Sheets.Add(After:=Sheets(1)).Name = "抽出"
　　　ActiveSheet.Paste
　　　Columns(1).Delete
　　　Range("A1").CurrentRegion.Borders.LineStyle = True
　　　Cells.Replace What:="集計", Replacement:="", LookAt:=xlPart, _
　　　　SearchOrder:=xlByRows, MatchCase:=False, _
　　　　SearchFormat:=False, ReplaceFormat:=False
　　　Sheets(1).Activate
　With Range("A1").CurrentRegion
　　　.RemoveSubtotal
　　　.Sort key1:=.Columns(1), order1:=xlAscending, Header:=xlYes
　End With
　　　Sheets("抽出").Activate
Application.ScreenUpdating = True
End Sub

3行目【With Range(“A1”).CurrentRegion】
A1セルからのデータ範囲をRange【ﾚﾝｼﾞ】オブジェクトのCurrentRegion【ｶﾚﾝﾄﾘｰｼﾞｮﾝ】プロパティで参照してWith【ｳｨｽﾞ】ステートメントで指定します。

4行目【.Sort key1:=.Columns(2), order1:=xlAscending, Header:=xlYes】
With【ｳｨｽﾞ】ステートメントで指定したRange【ﾚﾝｼﾞ】オブジェクトのSort【ｿｰﾄ】メソッドで2列目の担当者を基準に並び替え実行します。担当者をグループの基準にして集計を行うため、日毎に散らばっている担当者を並び替えでひと集まりにします。

5行目～6行目
【.Subtotal GroupBy:=2, Function:=xlSum, TotalList:=Array(3), _
Replace:=True, PageBreaks:=False, SummaryBelowData:=True】
With【ｳｨｽﾞ】ステートメントで指定したRange【ﾚﾝｼﾞ】オブジェクトのSubtotal【ｻﾌﾞﾄｰﾀﾙ】メソッドで集計グループの基準を設定する引数GroupBy【ｸﾞﾙｰﾌﾟﾊﾞｲ】に2列目の担当者を指定し、集計方法を設定する引数Function【ﾌｧﾝｸｼｮﾝ】に合計を表す「xlSum」を指定して集計する列を配列で指定する引数TotalList【ﾄｰﾀﾙﾘｽﾄ】には、Array【ｱﾚｲ】関数で配列に売上列の3列目を指定します。

8行目【ActiveSheet.Outline.ShowLevels RowLevels:=2】
Worksheet【ﾜｰｸｼｰﾄ】オブジェクトのOutline【ｱｳﾄﾗｲﾝ】プロパティを使用してアウトラインを表すOutline【ｱｳﾄﾗｲﾝ】オブジェクトを参照し、Outline【ｱｳﾄﾗｲﾝ】オブジェクトのShowLevels【ｼｮｳﾚﾍﾞﾙｽﾞ】メソッドを使用してアウトラインの行の折りたたみレベルを2に設定して、集計行だけを表示しています。レベルは1～3まであり、レベル1が個々のデータの下に集計行が入った、すべて表示。レベル2は集計行だけのデータ表示。　レベル3は総計だけの表示になります。

9行目【 Range(“A1”).CurrentRegion.SpecialCells(xlCellTypeVisible).Copy】
Range【ﾚﾝｼﾞ】オブジェクトのCurrentRegion【ｶﾚﾝﾄﾘｰｼﾞｮﾝ】プロパティでA1セルから始まる表範囲を選択して、Range【ﾚﾝｼﾞ】オブジェクトの特定のセルを参照するSpecialCells【ｽﾍﾟｼｬﾙｾﾙｽﾞ】メソッドの引数にxlCellTypeVisible【ｴｯｸｽｴﾙﾀｲﾌﾟﾋﾞｼﾞﾌﾞﾙ】を設定してレベル2で集計行だけ表示されているシートの表示されている部分だけを参照し、Range【ﾚﾝｼﾞ】オブジェクトのCopy【ｺﾋﾟｰ】メソッドで可視セルの値をコピーします。

10行目【Sheets.Add(After:=Sheets(1)).Name = “抽出”】
Sheets【ｼｰﾂ】コレクションのAdd【ｱﾄﾞ】メソッドを使用して「抽出」という名前のシートを追加しています。

11行目【ActiveSheet.Paste】
10行目で追加した抽出シートがアクティブになっているので、Worksheet【ﾜｰｸｼｰﾄ】オブジェクトのPaste【ﾍﾟｰｽﾄ】メソッドを使用して9行目でコピーしてクリップボードに保管されている、集計データを追加した抽出シートに貼り付けます。

12行目【Columns(1).Delete】
アクティブになっている抽出シートのColumns【ｶﾗﾑｽ】プロパティで参照した1列目、つまり売上日の列を削除しています。

13行目【Range(“A1”).CurrentRegion.Borders.LineStyle = True】
アクティブになっている抽出シートのA1セルからRange【ﾚﾝｼﾞ】オブジェクトのCurrentRegion【ｶﾚﾝﾄﾘｰｼﾞｮﾝ】プロパティで表範囲を参照し、Range【ﾚﾝｼﾞ】オブジェクトのBorders【ﾎﾞｰﾀﾞｰｽﾞ】プロパティで、セルの罫線を表すBorders【ﾎﾞｰﾀﾞｰｽﾞ】オブジェクトを取得して、Borders【ﾎﾞｰﾀﾞｰｽﾞ】オブジェクトの罫線の種類を設定するLineStyle【ﾗｲﾝｽﾀｲﾙ】プロパティにTrueを設定して選択範囲のセルの4辺に罫線を引きます。

14行目～16行目
【Cells.Replace What:=”集計”, Replacement:=””, LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, _
SearchFormat:=False, ReplaceFormat:=False】
cells【ｾﾙｽﾞ】プロパティでアクティブな抽出シートセル全体を参照し、Range【ﾚﾝｼﾞ】オブジェクトのReplace【ﾘﾌﾟﾚｲｽ】メソッドを使用して「集計」の文字列を「””」空白に置き換えます。

17行目【Sheets(1).Activate】
Worksheet【ﾜｰｸｼｰﾄ】オブジェクトのActivate【ｱｸﾃｨﾍﾞｲﾄ】メソッドでSheets【ｼｰﾂ】プロパティの引数で指定したインデックス番号1のシート、つまり元のデータがあるシートをアクティブにします。

18行目【With Range(“A1”).CurrentRegion】
元のデータがあるシートのA1セルから始まる表範囲をRange【ﾚﾝｼﾞ】オブジェクトのCurrentRegion【ｶﾚﾝﾄﾘｰｼﾞｮﾝ】プロパティで参照して、With【ｳｨｽﾞ】ステートメントで指定します。

19行目【.RemoveSubtotal】
With【ｳｨｽﾞ】ステートメントで指定した表範囲をRange【ﾚﾝｼﾞ】オブジェクトのRemoveSubtotal【ﾘﾑｰﾌﾞｻﾌﾞﾄｰﾀﾙ】メソッドを使用して5~6行目で実行したSubtotal【ｻﾌﾞﾄｰﾀﾙ】メソッドで追加された集計行とアウトラインを削除します。

20行目【.Sort key1:=.Columns(1), order1:=xlAscending, Header:=xlYes】
With【ｳｨｽﾞ】ステートメントで指定した表範囲をRange【ﾚﾝｼﾞ】オブジェクトのSort【ｿｰﾄ】メソッドを使用して並べ替えます。4行目のSort【ｿｰﾄ】メソッドで担当者を基準に並べ替えを実行したので、最初の売上日順に並べ替えます。

22行目【Sheets(“抽出”).Activate】
「抽出シート」をアクティブにします。

25行目【Application.ScreenUpdating = True】
抑止していた画面更新を再開します。