Excel VBA Excelで作成した表をWordドキュメントに書き出す

• オブジェクト（必須）
  Wordドキュメントを表すオブジェクト変数を指定します。
• Text【ﾃｷｽﾄ】
  Wordドキュメントに挿入する文字列を文字列型(String)で指定します。

• オブジェクト（必須）
  段落を追加するWordドキュメントを表す、オブジェクト変数を指定します。

• オブジェクト（必須）
  Excelの表を貼り付けるWordドキュメントを表すオブジェクト変数を指定します。
• LinkedToExcel【ﾘﾝｸﾂﾄｩｴｸｾﾙ】（必須）
  貼り付けた表を元のExcelの表とリンクさせるかどうかをブール型(Boolean)の値で設定します。

  設定値	内容
  False	リンクしません。
  True	リンクします。

• WordFormatting【ﾜｰﾄﾞﾌｫｰﾏｯﾃｨﾝｸﾞ】（必須）
  表の書式をExcelの書式を使用するかしないかをブール型(Boolean)の値で設定します。

  設定値	内容
  False	元のExcelの書式を引き継ぎます。
  True	Wordの書式を使用して設定します。

• RTF【ﾘｯﾁﾃｷｽﾄﾌｧｲﾙ】（必須）
  表の貼付け形式をブール型(Boolean)の値で設定します。

  設定値	内容
  False	HTML形式で貼り付けます。
  True	リッチ テキスト形式 (RTF) で貼り付けます。

Sub 表書き出し()
Dim ワード As New Word.Application
Dim 文書 As Word.Document
Dim 名前 As String
Dim パス As String
名前 = InputBox("ワードのファイル名を入力してください")
パス = ThisWorkbook.Path & "¥" & 名前 & ".docx"
Set 文書 = ワード.Documents.Add
With 文書
.ActiveWindow.Selection.TypeText Text:=Range("A1").Value
.ActiveWindow.Selection.TypeParagraph
Range("A2:E14").Copy
.ActiveWindow.Selection.PasteExcelTable False, False, False
.SaveAs2 パス
.Close
End With
MsgBox パス & "にワード文書を追加しました。"
Set 文書 = Nothing
ワード.Quit: Set ワード = Nothing
Application.CutCopyMode = False
End Sub

3行目【Dim 文書 As Word.Document】
Wordドキュメントを表す変数「文書」をオブジェクト型(Word.Document)で宣言します。

4行目【Dim 名前 As String】
新規Wordドキュメントを保存するときの名前を格納する変数「名前」を文字列型(String)で宣言します。

5行目【Dim パス As String】
新規Wordドキュメントのパスと変数名前に格納されている文書名を格納する変数パスを文字列型(String)で宣言します。

6行目【名前 = InputBox(“ワードのファイル名を入力してください”)】
InputBox【ｲﾝﾌﾟｯﾄﾎﾞｯｸｽ】関数を使用してユーザーからWordドキュメントのファイル名を受け取り変数「名前」に代入します。

7行目【パス = ThisWorkbook.Path & “¥” & 名前 & “.docx”】
新規で開くWordドキュメントのパスを含めた名前を変数「パス」に代入します。ThisWorkbook.Pathでこのコードが記述されているExcelファイルと同じパス（場所）のユーザーが入力して変数に格納した変数「名前」のWordドキュメントファイルを設定して代入します。

8行目【Set 文書 = ワード.Documents.Add】
WordApplication【ﾜｰﾄﾞｱﾌﾟﾘｹｰｼｮﾝ】のインスタンス（複製）が格納されている変数「ワード」オブジェクトのDocuments【ﾄﾞｷｭﾒﾝﾂ】オブジェクトのAdd【ｱﾄﾞ】メソッドを使用して新しいWordドキュメントを作成しSetキーワードを使用してオブジェクト型変数「文書」に格納します。

9行目【With 文書】
Add【ｱﾄﾞ】メソッドで作成されたWordドキュメントが格納されている変数「文書」をWith【ｳｨｽﾞ】ステートメントで指定します。

10行目【.ActiveWindow.Selection.TypeText Text:=Range(“A1”).Value】
With【ｳｨｽﾞ】ステートメントで指定したWordドキュメントのTypeText【ﾀｲﾌﾟﾃｷｽﾄ】メソッドを使用してWordドキュメントに文字列を書き出します。書き出す文字列をしていする、引数TextにExcelのA1セルの値をValue【ﾊﾞﾘｭｰ】プロパティで取得し設定します。

11行目【.ActiveWindow.Selection.TypeParagraph】
With【ｳｨｽﾞ】ステートメントで指定したワードドキュメントのTypeParagraph【ﾀｲﾌﾟﾊﾟﾗｸﾞﾗﾌ】メソッドを使用してWordドキュメントに段落を設定します。

12行目【Range(“A2:E14”).Copy】
Excelの表範囲をRange【ﾚﾝｼﾞ】プロパティで指定して、Range【ﾚﾝｼﾞ】オブジェクトのCopy【ｺﾋﾟｰ】メソッドでその範囲をコピーします。

13行目【.ActiveWindow.Selection.PasteExcelTable False, False, False】
With【ｳｨｽﾞ】ステートメントで指定したWordドキュメントのPasteExcelTable【ﾍﾟｰｽﾄｴｸｾﾙﾃｰﾌﾞﾙ】メソッドを使用してコピーしたExcelの表を指定したWordドキュメントに貼り付けます。

14行目【.SaveAs2 パス】
WordApplication【ﾜｰﾄﾞｱﾌﾟﾘｹｰｼｮﾝ】オブジェクトのSaveAs2【ｾｰﾌﾞｱｽﾞﾂｰ】メソッドを使用してWith【ｳｨｽﾞ】ステートメントで指定したワードドキュメントを変数「パス」に格納されている名前を付けて保存します。

15行目【.Close】
WordApplication【ﾜｰﾄﾞｱﾌﾟﾘｹｰｼｮﾝ】オブジェクトのClose【ｸﾛｰｽﾞ】メソッドを使用してWith【ｳｨｽﾞ】ステートメントで指定したワードドキュメントを閉じます。

17行目【MsgBox パス & “にワード文書を追加しました。”】
MsgBox関数を使用してWordドキュメントの保存先と書き出しが終了したことをユーザーに伝えます。

18行目【Set 文書 = Nothing】
オブジェクト変数「文書」にNothing【ﾅｯｼﾝｸﾞ】を代入してWordドキュメントへの参照を解放します。

19行目【ワード.Quit: Set ワード = Nothing】
WordApplication【ﾜｰﾄﾞｱﾌﾟﾘｹｰｼｮﾝ】オブジェクトのQuit【ｸｴｲﾄ】メソッドを使用してワードを終了させてワードのインスタンスが格納されているオブジェクト変数「ワード」にNothingを代入してWordApplicationへの参照を解放します。

20行目【Application.CutCopyMode = False】
Application【ｱﾌﾟﾘｹｰｼｮﾝ】オブジェクトのCutCopyMode【ｶｯﾄｺﾋﾟｰﾓｰﾄﾞ】プロパティにFalseを設定してワークシートのコピーモードを解除します。