VBA セルに条件付き書式を設定する

セルに条件付き書式を設定する方法

セルに条件書式を設定するには、Range【ﾚﾝｼﾞ】オブジェクトに含まれる条件付き書式の集まりであるFormatConditions【ﾌｫｰﾏｯﾄｺﾝﾃﾞｨｼｮﾝｽﾞ】コレクションのAdd【ｱﾄﾞ】メソッドを使用して、条件付き書式を表すFormatCondition【ﾌｫｰﾏｯﾄｺﾝﾃﾞｨｼｮﾝ】オブジェクトを作成します。

作成したFormatCondition【ﾌｫｰﾏｯﾄｺﾝﾃﾞｨｼｮﾝ】オブジェクトに対して、Font【ﾌｫﾝﾄ】プロパティ、Interior【ｲﾝﾃﾘｱ】プロパティ、Border【ﾎﾞｰﾀﾞｰ】プロパティなどを使用して書式を設定します。

FormatConditionsコレクションのAddメソッドの書式と設定値(引数)の説明

[]内は省略可能です。
オブジェクト.Add(type[,Operator,Formula1,Formula2])
【戻り値】FormatCondition【ﾌｫｰﾏｯﾄｺﾝﾃﾞｨｼｮﾝ】オブジェクト

条件付き書式は、指定したセル範囲に複数指定することができます。条件書式を設定するプロシージャを実行すると、実行のたびに条件付き書式が追加されます。

条件付き書式を削除する方法

指定されたセル範囲に設定されている条件書式を削除するには、FormatConditions【ﾌｫｰﾏｯﾄｺﾝﾃﾞｨｼｮﾝｽﾞ】コレクションのDelete【ﾃﾞﾘｲﾄ】メソッドを使用して以下のように記述します。
「セル範囲.FormatConditions.Delete」
シート全体の設定されている条件書式を削除するには、「Cells.FormatConditions.Delete」と記述します。

不要な条件付き書式を削除しておく方法

条件付き書式を追加すると、すでに設定されている条件付き書式に加えて新しく条件付き書式が追加されます。複数の条件付き書式を追加するのでなければ、不要な条件付き書式を削除してから設定し直します。

選択範囲にすでに条件書式が設定されているかを、FormatConditions【ﾌｫｰﾏｯﾄｺﾚｸｼｮﾝｽﾞ】コレクションのCount【ｶｳｳﾝﾄ】プロパティで調べ、値が0でなかったら（条件付き書式が設定されていたら）設定されている条件付き書式を削除するコード例は以下のようになります。

A列の2行目から条件があることを想定して、条件付き書式が設定されていたら条件付き書式を削除するコード例

Sub 条件削除()
Dim 最終行 As Long
最終行 = Cells(Rows.Count, 1).End(xlUp).Row
If Range("A2", "A" & 最終行).FormatConditions.Count <> 0 Then
Range("A2", "A" & 最終行).FormatConditions.Delete
End If
End Sub

A列のセルの値が100より大きい場合に文字を太くして背景色を赤にするコード例

Sub 条件書式1()
Dim 最終行 As Long
最終行 = Cells(Rows.Count, 1).End(xlUp).Row
If Range("A2", "A" & 最終行).FormatConditions.Count <> 0 Then
Range("A2", "A" & 最終行).FormatConditions.Delete
End If
With Range("A2", "A" & 最終行).FormatConditions.Add _
(Type:=xlCellValue, Operator:=xlGreater, Formula1:=100)
.Font.Bold = True
.Interior.Color = RGB(250, 0, 0)
End With
End Sub

引数typeをxltextString(テキスト文字例)に設定した場合のコード例

A列に文字列「山」が含まれている文字列のフォントを太くして背景を赤にする例

Sub 条件書式2()
Dim 最終行 As Long
最終行 = Cells(Rows.Count, 1).End(xlUp).Row
If Range("A2", "A" & 最終行).FormatConditions.Count <> 0 Then
Range("A2", "A" & 最終行).FormatConditions.Delete
End If
With Range("A2", "A" & 最終行).FormatConditions.Add _
(Type:=xlTextString, String:="山", TextOperator:=xlContains)
.Font.Bold = True
.Interior.Color = RGB(250, 0, 0)
End With
End Sub

• 引数Typeの条件をxlTextStringでテキスト文字列にした場合
  引数TextOperatorで引数Stringに対する条件の判断方法をxlContainsOperator列挙型の定数で指定します

指定した期間の場合に書式を設定する

A列に入力されている日付で今週の文字を太くしてセルを赤く塗りつぶすコード例

Sub 条件書式日付()
Dim 最終行 As Long
最終行 = Cells(Rows.Count, 1).End(xlUp).Row
If Range("A2", "A" & 最終行).FormatConditions.Count <> 0 Then
Range("A2", "A" & 最終行).FormatConditions.Delete
End If
With Range("A2", "A" & 最終行).FormatConditions.Add _
(Type:=xlTimePeriod, DateOperator:=xlThisWeek)
.Font.Bold = True
.Interior.Color = RGB(250, 0, 0)
End With
End Sub

• 引数Typeの条件をxlTimePeriodで期間にした場合
  引数DateOperatorで期間をxlTimePeriod列挙型の定数で指定します

以上で、条件付き書式の設定についての解説を終了します。ありがとうございました。