Excel VBA 入力されたデータの表記を統一する

• String【ｽﾄﾘﾝｸﾞ】（必須）
  種類を変換したい文字列を指定します。
• Conversion【ｺﾝﾊﾞｰｼｮﾝ】（必須）
  変換する種類をVbStrConv列挙型の定数または値で指定します。

  VbStrConv列挙型

  定数	値	内容
  vbUpperCase	1	文字列を大文字に変換
  vbLowerCase	2	文字列を小文字に変換
  vbProperCase	3	文字列の各単語の先頭の文字を大文字に変換
  vbWide	4	文字列内の半角文字を全角文字に変換
  vbNarrow	8	文字列内の全角文字を半角文字に変換
  vbKatakana	16	文字列内のひらがなをカタカナに変換
  vbHiragana	32	文字列内のカタカナをひらがなに変換
  vbUnicode	64	システムの既定のコードページを使って文字列をUnicodeに変換
  vbFromUnicode	128	文字列をUnicodeからシステムの既定のコードページに変換

• LocaleID【ﾛｰｶﾙｱｲﾃﾞｨ】（省略可）
  「国別情報識別子」を指定します。システムとは異なる「国別情報識別子」を指定できます。
  省略した場合は、システムで使用している「国別情報識別子」が指定されます。

Sub 変換()
Dim 最終行 As Long
Dim 最終列 As Long
Dim 行 As Long
Dim 列 As Long
 最終行 = Cells(Rows.Count, 1).End(xlUp).Row
 最終列 = Cells(1, Columns.Count).End(xlToLeft).Column
Application.ScreenUpdating = False
 For 行 = 1 To 最終行
  For 列 = 1 To 最終列
   Cells(行, 列).Value = StrConv(Cells(行, 列).Value, vbNarrow + vbKatakana)
  Next 列
 Next 行
Application.ScreenUpdating = True
End Sub

3行目【Dim 最終列 As Long】
データが入力されている最終列番号を格納する変数「最終列」を長整数型(Long)で宣言します。

4行目【Dim 行 As Long】
繰り返し処理の中で行番号を表す1~最終行番号が代入されるカウンター変数「行」を長整数型(Long)で宣言します。

5行目【Dim 列 As Long】
繰り返し処理の中で列番号を表す1~最終列番号が代入されるカウンター変数「列」を長整数型(Long)で宣言します。

6行目【最終行 = Cells(Rows.Count, 1).End(xlUp).Row】
Rows.Countプロパティで取得したセルの最終行からRange【ﾚﾝｼﾞ】オブジェクトのEnd【ｴﾝﾄﾞ】プロパティを使用してデータが入力されている行を参照してRow【ﾛｳ】プロパティでその行番号を取得して変数「最終行」に代入します。

7行目【最終列 = Cells(1, Columns.Count).End(xlToLeft).Column】
Columns.Countプロパティで取得したセルの最終列からRange【ﾚﾝｼﾞ】オブジェクトのEnd【ｴﾝﾄﾞ】プロパティを使用してデータが入力されている列を参照してColumn【ｶﾗﾑ】プロパティでその列番号を取得して変数「最終列」に代入します。

8行目【Application.ScreenUpdating = False】
Application【ｱﾌﾟﾘｹｰｼｮﾝ】オブジェクトのScreenUpdating【ｽｸﾘｰﾝｱｯﾌﾟﾃﾞｨｰﾃｨﾝｸﾞ】プロパティにFalseを設定して、画面の更新を抑止してメモリの使用抑止と処理の高速化を図ります。

9行目【For 行 = 1 To 最終行】
For Next【ﾌｫｰﾈｸｽﾄ】ステートメントを使用して繰り返し処理を実行します。行番号を表すカウンター変数「行」に1~データの最終行番号の値が順次代入されます。

10行目【For 列 = 1 To 最終列】
ネスト（入れ子）のFor Next【ﾌｫｰﾈｸｽﾄ】ステートメントを使用して繰り返し処理を実行します。列番号を表すカウンター変数「列」に1~データの最終列番号の値が順次代入されます。

11行目【Cells(行, 列).Value = StrConv(Cells(行, 列).Value, vbNarrow + vbKatakana)】
繰り返し処理の中でStrConv【ｽﾄﾘﾝｸﾞｺﾝﾊﾞｰｼｮﾝ】関数で変換したセルの値をそのセルに代入します。