Excel VBA 作成した図を透過画像ファイル(PNG)で書き出す

• オブジェクト（必須）
  ブック内のグラフを表すChart【ﾁｬｰﾄ】オブジェクトを指定します。
• Filename【ﾌｧｲﾙﾈｰﾑ】（必須）
  書き出すファイルのファイル名と拡張子を指定します。
• FilterName【ﾌｨﾙﾀｰﾈｰﾑ】（省略可）
  レジストリに表示されるグラフィック フィルターの言語非依存の名前を指定します。
• Interactive【ｲﾝﾀｰｱｸﾃｨﾌﾞ】（省略可）
  True を指定すると、フィルター固有のオプションを含むダイアログ ボックスが表示されます。 False を指定すると、フィルターの既定値が使用されます。既定値は False です。

Sub sample()
MsgBox "ブックを任意の場所に一旦保存して" & vbCrLf & _
"画像ファイルを書き出すパス（場所）を確定してください。"
With Application.FileDialog(msoFileDialogSaveAs)
.InitialFileName = ThisWorkbook.Path & "¥"
.FilterIndex = 2
If .Show = -1 Then .Execute
End With
With ThisWorkbook.Sheets(1)
    .Activate
With .Shapes
If .Count >= 2 Then
     .SelectAll
     Selection.Group.Name = "ロゴ"
 Else
     .SelectAll
    Selection.Name = "ロゴ"
End If
End With
End With
With ActiveSheet.Shapes("ロゴ")
  .CopyPicture
ActiveSheet.ChartObjects.Add(0, 0, .Width, .Height).Name = "貼付用"
End With
With ActiveSheet.ChartObjects("貼付用")
  .Chart.PlotArea.Fill.Visible = msoFalse
  .Chart.ChartArea.Fill.Visible = msoFalse
  .Chart.ChartArea.Border.LineStyle = 0
End With
  Application.OnTime Now + TimeValue("00:00:03"), "sample2"
End Sub
Private Sub sample2()
With ActiveSheet.ChartObjects("貼付用")
  .Chart.Paste
  .Chart.Export ThisWorkbook.Path & "¥ロゴ.png"
  .Delete
  MsgBox ThisWorkbook.Path & "にpngファイルを出力しました。"
End With
End Sub

4行目【With Application.FileDialog(msoFileDialogSaveAs)】
Application【ｱﾌﾟﾘｹｰｼｮﾝ】オブジェクトのFileDialog【ﾌｧｲﾙﾀﾞｲｱﾛｸﾞ】オブジェクトを使用して
引数のtypeを名前を付けて保存ダイアログに指定して、With【ｳｨｽﾞ】ステートメントで指定します。

5行目【.InitialFileName = ThisWorkbook.Path & “¥”】
With【ｳｨｽﾞ】ステートメントで指定したFileDialogオブジェクトに対してInitialFileName【ｲﾆｼｬﾙﾌｧｲﾙﾈｰﾑ】プロパティで
保存ダイアログに初めに表示される保存パス(場所)を設定します。ThisWorkbookオブジェクトのPath【ﾊﾟｽ】プロパティでこのプロシージャが記述されているブックの場所に設定します。

6行目【.FilterIndex = 2】
With【ｳｨｽﾞ】ステートメントで指定したFileDialogオブジェクトに対してFilterIndex【ﾌｧｲﾙｲﾝﾃﾞｸｽ】プロパティで
保存ダイアログに初めに表示されるファイル保存形式を2の「エクセル マクロ有効ブック(*xlsm)」に設定しています。

7行目【If .Show = -1 Then .Execute】
With【ｳｨｽﾞ】ステートメントで指定したFileDialogオブジェクトに対してIf文(条件分岐)でShow【ｼｮｳ】メソッドが-1だったら、つまりダイアログのアクションボタンがクリックされたらExecute【ｴｸｽｷｭｰﾄ】メソッドでアクションを実行するを定義します。

9行目【With ThisWorkbook.Sheets(1)】
ThisWorkbook【ﾃﾞｨｽﾜｰｸﾌﾞｯｸ】プロパティで参照したこのプロシージャが記述されているブックを表すThisWorkbook【ﾃﾞｨｽﾜｰｸﾌﾞｯｸ】オブジェクトのSheets【ｼｰﾂ】プロパティで参照したインデックス番号1のシートをWith【ｳｨｽ】ステートメントで指定します。

10行目【.Activate】
With【ｳｨｽ】ステートメントで指定した上記のシートに対してWorksheet【ﾜｰｸｼｰﾄ】オブジェクトのActivate【ｱｸﾃｨﾍﾞｲﾄ】メソッドでそのシートをアクティブにします。

11行目【With .Shapes】
Withステートメントで指定した上記のシートの図の集まりを表すShapes【ｼｪｲﾌﾟｽ】コレクションをWith【ｳｨｽﾞ】ステートメントで指定します。

12行目【If .Count >= 2 Then】
If【ｲﾌ】ステートメントを使用しで条件分岐をします。条件式としてWith【ｳｨｽﾞ】ステートメントで指定した図形の集まりを表すShapes【ｼｪｲﾌﾟｽ】コレクションのCount【ｶｳﾝﾄ】メソッドを使用してジート内の図の数を取得して、比較演算子「>=」
を使用してシート内の図形の数が2個以上の場合を定義します。

13行目【.SelectAll】
シートに図が2個以上ある場合Shapes【ｼｪｲﾌﾟｽ】コレクションのSelectAll【ｾﾚｸﾄｵｰﾙ】メソッドですべての図を選択状態にします。

14行目【Selection.Group.Name = “ロゴ”】
選択されている図をGroup【ｸﾞﾙｰﾌﾟ】メソッドでグループ化しName【ﾈｰﾑ】プロパティで「ロゴ」という名前に設定します。

15～17行目
【Else
.SelectAll
Selection.Name = “ロゴ”】
Else【ｴﾙｽﾞ】ステートメントで条件に一致しなかった場合、つまりシートに図が1個しかない場合を定義します。図が1個しかない場合はグループ化のメソッドを実行するとエラーになるのでグループ化をしないで、図に「ロゴ」という名前を付けます。

21行目【With ActiveSheet.Shapes(“ロゴ”)】
上記で作成したロゴと名前を付けた図をShapes【ｼｪｲﾌﾟｽ】プロパティで参照してWith【ｳｨｽﾞ】ステートメントで指定します。

22行目【 .CopyPicture】
With【ｳｨｽﾞ】ステートメントで指定した図を表すShape【ｼｪｲﾌﾟ】オブジェクトの
CopyPicture【ｺﾋﾟｰﾋﾟｸﾁｬｰ】メソッドで作成した図を図としてコピーします。

23行目【ActiveSheet.ChartObjects.Add(0, 0, .Width, .Height).Name = “貼付用”】Worksheet【ﾜｰｸｼｰﾄ】オブジェクトの埋め込みグラフを表すChartObjects【ﾁｬｰﾄｵﾌﾞｼﾞｪｸﾂ】オブジェクトのAdd【ｱﾄﾞ】 メソッドで埋め込みグラフシートを作成します。引数は(ｼｰﾄ左位置,上位置,ｼｰﾄ幅,高さ)、ここでは（0,0,Shapesの幅,Shapesの高さ）で指定しています。最後にName【ﾈｰﾑ】プロパティでこの埋め込みグラフの名前を「貼付用」に指定しています。

25行目～28行目
【With ActiveSheet.ChartObjects(“貼付用”)
.Chart.PlotArea.Fill.Visible = msoFalse
.Chart.ChartArea.Fill.Visible = msoFalse
.Chart.ChartArea.Border.LineStyle = 0】
埋め込みグラフを表すChartObjects【ﾁｬｰﾄｵﾌﾞｼﾞｪｸﾂ】自体を透明設定します。

30行目【Application.OnTime Now + TimeValue(“00:00:03”), “sample2″】ChartObjects【ﾁｬｰﾄｵﾌﾞｼﾞｪｸﾂ】を作成直後の画像の貼付けが失敗する可能性があるので指定された時刻 にプロシージャを実行するApplication【ｱﾌﾟﾘｹｰｼｮﾝ】オブジェクトのOnTime【ｵﾝﾀｲﾑ】 メソッドでNow + TimeValue(“00:00:03”)現在の時刻から3秒まって次のsample2プロシージャ―に実行を移しています。

32行目【Private Sub sample2()】
Private Sub【ﾌﾟﾗｲﾍﾞｰﾄｻﾌﾞ】プロシージャにして30行目のOnTimeメソッドからしか、プロシージャを呼び出せないようにします。

33行目【With ActiveSheet.ChartObjects(“貼付用”)】
With【ｳｨｽﾞ】ステートメントでChartObjects(“貼付用”)を指定します。

34行目【.Chart.Paste】
With【ｳｨｽﾞ】ステートメントで指定されたChartObjects(“貼付用”)に22行目でコピーしてクリップボード保存した図をChart【ﾁｬｰﾄ】オブジェクトのPaste【ﾍﾟｰｽﾄ】メソッドを使用して貼り付けます。

35行目【 .Chart.Export ThisWorkbook.Path & “¥ロゴ.png”】
グラフを画像として書き出すChart.Export【ﾁｬｰﾄｴｸｽﾎﾟｰﾄ】メソッドで、このブックのパスにロゴ.pngでpng形式の画像ファイルとして書き出します。

36行目【.Delete】
DeleteメソッドでWith【ｳｨｽﾞ】ステートメントで指定したChartObjects(“貼付用”)を削除します。

37行目【 MsgBox ThisWorkbook.Path & “にpngファイルを出力しました。”】
ファイルの書き出しができたことをメッセージボックスで伝えます。