Excel VBA ピボットテーブルを作成する

• オブジェクト（必須）
  PivotCaches【ﾋﾟﾎﾞｯﾄｷｬｯｼｰｽﾞ】コレクションを指定します。
  PivotCaches【ﾋﾟﾎﾞｯﾄｷｬｯｼｰｽﾞ】コレクションはWorkbook【ﾜｰｸﾌﾞｯｸ】オブジェクトのPivotCaches【ﾋﾟﾎﾞｯﾄｷｬｯｼｰｽﾞ】プロパティで取得します。
• SourceType【ｿｰｽﾀｲﾌﾟ】（必須）
  xlPivottableSourceType列挙型の定数で元データの種類を指定します。

  xlPivottableSourceType列挙型の定数

  定数	値	内容
  xlDatabase	1	Excelの表
  xlExternal	2	外部アプリケーションデータ
  xlConsolidation	3	複数のワークシート範囲
  xlScenario	4	[シナリオの登録と管理] を 使用して作成されたシナリオに基づきます。
  xlPivotTable	-4148	既存のピボットテーブル レポート

• SourceData【ｿｰｽﾃﾞｰﾀ】（省略可）
  新しいピボットテーブルキャッシュのデータを指定します。引数SourcType【ｿｰｽﾀｲﾌﾟ】がxlDatabase(Excelの表)、またはxlConsolidation(複数のワークシート範囲)の場合はデータ元となるセル範囲を指定します。
• Version【ﾊﾞｰｼﾞｮﾝ】（省略可）
  ピボットテーブルのバージョンをxlPivotTableVersionList列挙型の定数、または値で指定します。

  xlPivotTableVersionList列挙型の主な定数

  定数	値	内容
  xlPivotTableVersion11	2	Excel 2003
  xlPivotTableVersion12	3	Excel 2007
  xlPivotTableVersion14	4	Excel 2010
  xlPivotTableVersion15	5	Excel 2013
  	6	Excel 2016

※省略した場合はxlPivotTableVersion12(Excel2007)になりますが、Excel2016/2013/2010でも動作します。Excel2016のバージョンを指定する場合は定数ではなく値の6を指定してください。

• オブジェクト（必須）
  PivotCache【ﾋﾟﾎﾞｯﾄｷｬｯｼｭ】オブジェクトを指定します。
• TableDestination【ﾃｰﾌﾞﾙﾃﾞｨｽﾃｨﾈｰｼｮﾝ】（必須）
  作成するピボットテーブルの左上端のセルを指定します。ピボットテーブルキャッシュを作成したブック内のセルを指定してください。
• TableName【ﾃｰﾌﾞﾙﾈｰﾑ】（省略可）
  ピボットテーブル名を指定します。省略した場合は「ピボットテーブル1」のような名前が自動で設定されます。

• オブジェクト（必須）
  PivotTable【ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ】オブジェクトを指定します。
• Index【ｲﾝﾃﾞｯｸｽ】（省略可）
  参照したいフィールドのインデックス番号または、フィールド名を文字列で指定します。

• オブジェクト（必須）
  PivotField【ﾋﾟﾎﾞｯﾄﾌｨｰﾙﾄﾞ】オブジェクトを指定します。
  PivotField【ﾋﾟﾎﾞｯﾄﾌｨｰﾙﾄﾞ】オブジェクトはPivotTable【ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ】オブジェクトのPivotFields【ﾋﾟﾎﾞｯﾄﾌｨｰﾙｽﾞ】メソッドで取得できます。
• 設定値（必須）
  xlPivotFieldOrientation列挙型の定数で追加先のフィールドを指定します。

  xlPivotFieldOrientation列挙型の定数

  定数	値	内容
  xlHidden	0	非表示
  xlRowField	1	行
  xlColumnField	2	列
  xlPageField	3	ページ
  xlDataField	4	値

• オブジェクト（必須）
  値フィールドを参照するPivotField【ﾋﾟﾎﾞｯﾄﾌｨｰﾙﾄﾞ】オブジェクトを指定します。
• 設定値（必須）
  集計方法をxlConsolidationFunction列挙型の定数で指定します。

  xlConsolidationFunction列挙型の定数

  定数	値	内容
  xlSum	-4157	合計
  xlAverage	-4106	平均
  xlCount	-4112	個数
  xlCountNums	-4113	数値の個数
  xlMax	-4136	最大値
  xlMin	-4139	最小値
  xlProduct	-4149	積（掛け算）
  xlStDev	-4155	標本に基づく標準偏差
  xlStDevP	-4156	母集団全体に基づく標準偏差
  xlVar	-4164	標本に基づく変動
  xlVarP	-4165	母集団全体に基づく変動
  xlDistinctCount	111	Distinct Count 分析を使ったカウント
  xlUnknown	1000	小計に使用する関数は指定されません。

Sub ピボットテーブル作成()
Dim キャッシュ As PivotCache
Dim テーブル As PivotTable
Set キャッシュ = ActiveWorkbook.PivotCaches.Create _
(SourceType:=xlDatabase, SourceData:=Range("A1").CurrentRegion)
Set テーブル = キャッシュ.CreatePivotTable _
(tabledestination:=Range("F1"), TableName:="7月度事業別売上")
With テーブル
.PivotFields("事業").Orientation = xlRowField
.PivotFields("店名").Orientation = xlColumnField
With .PivotFields("売上")
.Orientation = xlDataField
.Function = xlSum
.NumberFormat = "#,##0"
End With
End With
End Sub

3行目【Dim テーブル As PivotTable】
ピボットテーブルを格納する変数「テーブル」をオブジェクト型(PivotTable)で宣言します。

4行目～5行目【Set キャッシュ = ActiveWorkbook.PivotCaches.Create _
(SourceType:=xlDatabase, SourceData:=Range(“A1”).CurrentRegion)】
Create【ｸﾘｴｲﾄ】メソッドでPivotCache【ﾋﾟﾎﾞｯﾄｷｬｯｼｭ】オブジェクトを取得して、Set【ｾｯﾄ】キーワードを使用してオブジェクト変数「キャッシュ」に代入します。

6行目～7行目【Set テーブル = キャッシュ.CreatePivotTable _
(tabledestination:=Range(“F1″), TableName:=”7月度事業別売上”)】
4行目～5行目で作成したピボットキャッシュからCreatePivotTable【ｸﾘｴｲﾄﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ】メソッドを使用して
ピボットテーブルを作成してSet【ｾｯﾄ】キーワードを使用してオブジェクト変数「テーブル」に代入します。

8行目【With テーブル】
PivotTable【ﾋﾟﾎﾞｯﾄﾃｰﾌﾞﾙ】オブジェクトが格納されているオブジェクト変数「テーブル」をWith【ｳｨｽﾞ】ステートメントで指定します。

9行目【.PivotFields(“事業”).Orientation = xlRowField】
PivotFields【ﾋﾟﾎﾞｯﾄﾌｨｰﾙｽﾞ】メソッドで「事業」列を参照しOrientation【ｵﾘｴﾝﾃｨｰｼｮﾝ】プロパティで行フィールドに追加します。

10行目【.PivotFields(“店名”).Orientation = xlColumnField】
「店名」列を参照して列フィールドに追加します。

11行目【With .PivotFields(“売上”)】
PivotFields【ﾋﾟﾎﾞｯﾄﾌｨｰﾙｽﾞ】メソッドで「売上」列を参照しWith【ｳｨｽﾞ】ステートメントで指定します。

12行目【.Orientation = xlDataField】
With【ｳｨｽﾞ】ステートメントで指定した「売上」フィールドに対してOrientation【ｵﾘｴﾝﾃｨｼｮﾝ】プロパティで「値」に指定します。

13行目【.Function = xlSum】
「売上」フィールドに対してFunction【ﾌｧﾝｸｼｮﾝ】プロパティを使用して集計方法を「合計」に指定します。

14行目【.NumberFormat = “#,##0″】
「売上」フィールドに対してNumberFormat【ﾅﾝﾊﾞｰﾌｫｰﾏｯﾄ】プロパティを使用して値を3桁区切りの書式を設定します。