Excel VBA チェックボックスの状態を取得する

• オブジェクト（必須）
  CheckBox【ﾁｪｯｸﾎﾞｯｸｽ】コントロールオブジェクトを表すオブジェクト名を指定します。
• 設定値　戻り値
  

  設定値・戻り値	内容
  True	チェックがされている状態
  False	チェックがはずれている状態
  Null	無効の状態

  ※Null（無効の状態）に設定するにはCheckBox【ﾁｪｯｸﾎﾞｯｸｽ】コントロールオブジェクトのTripleState【ﾄﾘﾌﾟﾙｽﾀｰﾄ】プロパティにTrueを設定する必要があります。

• Index【ｲﾝﾃﾞｯｸｽ】
  参照するコントロールのインデックス番号またはオブジェクト名を文字列で指定します。

Private Sub CommandButton1_Click()
Dim コントロール As Control
Dim チェック状態 As Boolean
　　チェック状態 = False
　For Each コントロール In Controls
　If TypeName(コントロール) = "CheckBox" Then
　　If コントロール.Value = True Then
　チェック状態 = True
　Exit For
　　End If
　End If
Next
　If チェック状態 = False Then
　　MsgBox "選択されていません。"
　Exit Sub
　End If
End Sub

2行目【Dim コントロール As Control】
フォームに配置されているコントロールオブジェクトを格納する変数「コントロール」をオブジェクト型(Control)で宣言します。

3行目【Dim チェック状態 As Boolean】
配置されているチェックボックスのチェック状態を格納する変数「チェック状態」をブール型(Boolean)で宣言します。

4行目【チェック状態 = False】
チェックボックスのチェック状態を格納する変数「チェック状態」に初期値としてチェックされていない状態を表すFalseを代入します。

5行目【For Each コントロール In Controls】
For Each【ﾌｧｱｲｰﾁ】ステートメントを使用して繰り返し処理の始まりです。フォーム上のすべてのコントロールを表すControls【ｺﾝﾄﾛｰﾙｽﾞ】コレクション内の個々のコントロールを表すControl【ｺﾝﾄﾛｰﾙ】オブジェクトを繰り返し処理の中で順に参照して変数「コントロール」に順に代入します。

6行目【If TypeName(コントロール) = “CheckBox” Then】
Ifステートメントで条件分岐をします。TypeName【ﾀｲﾌﾟﾈｰﾑ】関数を使用してコントロールオブジェクトが格納されている変数「コントロール」に格納されているコントロールがCheckBox【ﾁｪｯｸﾎﾞｯｸｽ】だったときを定義します。

7行目【If コントロール.Value = True Then】
6行目の条件分岐で変数「コントロール」に格納されているコントロールがチェックボックスの場合、If【ｲﾌ】ステートメントを使用してさらに条件分岐をします。CheckBox【ﾁｪｯｸﾎﾞｯｸｽ】コントロールオブジェクトのValue【ﾊﾞﾘｭｰ】プロパティでチェックボックスの状態を取得しTrue（チェックされている）のときを定義します。

8行目～9行目【チェック状態 = True
Exit For】
7行目の条件分岐が成立した場合、つまりチェックボックスにチェックがされている場合、チェックボックスのチェック状態を格納する変数「チェック状態」にチェックされている状態を表す「True」を代入しExit　Forステートメントを設定して繰り返し処理を途中で中断します。つまり、For Each【ﾌｧｱｲｰﾁ】ステートメントでフォーム上のコントロールの数、繰り返し処理をしますがチェックがされている状態のチェックボックスがみつかった時点で繰り返し処理を終了するということです。

13～15行目【If チェック状態 = False Then
MsgBox “必ず1つ以上選択してください。”
Exit Sub】
If【ｲﾌ】ステートメントで条件分岐です。チェックボックスのチェック状態が格納されている変数「チェック状態」がFalse　のときを定義します。つまり、5行目からの繰り返し処理で確認したチェックボックスのチェック状態がチェックされていない
状態を表すFalseだったときを表します。条件が成立した場合は、メッセージを表示してExit Sub【ｴｸﾞｼﾞｯﾄｻﾌﾞ】ステートメントでSub【ｻﾌﾞ】プロシージャーを途中で終了します。

Private Sub CommandButton1_Click()
Dim コントロール As Control
Dim チェック状態 As Boolean
　チェック状態 = False
　For Each コントロール In Controls
　　If TypeName(コントロール) = "CheckBox" Then
　　　If コントロール.Value = True Then
　　チェック状態 = True
　Exit For
　　　End If
　　End If
　Next
　　If チェック状態 = False Then
　　　MsgBox "選択されていません。"
　　　Exit Sub
　　End If

Dim 最終行 As Integer
　　最終行 = Worksheets("sheet1").Cells(Rows.Count, 1).End(xlUp).Row + 1
Dim i As Integer
　For i = 1 To 4
　　If Controls("checkbox" & i).Value = True Then
　　　Worksheets("sheet1").Cells(最終行, i).Value = "●"
　　Else
　　　Worksheets("sheet1").Cells(最終行, i).Value = "×"
　　End If
　Next i
End Sub

18行目
【Dim 最終行 As Integer】
セルのデータが入力されている最終行番号の次の行番号を格納する変数「最終行」を整数型(Integer)で宣言します。

19行目【最終行 = Worksheets(“sheet1”).Cells(Rows.Count, 1).End(xlUp).Row + 1】
sheet1のA列の最終セルからEnd【ｴﾝﾄﾞ】プロパティで引数をxlupに指定して最終セルから上方向にデータが入力されている終端セルを参照しRow【ﾛｳ】プロパティで行番号を取得して1を加算することでデータが入力されている終端セルの次の行の行番号を取得して変数「最終行」に代入します。

20行目【Dim i As Integer】
チェックボックスの数とセルの列番号を兼ねるカウンター変数「i」を整数型(Integer)で宣言します。

21行目【For i = 1 To 4】
For Next【ﾌｫｱﾈｸｽﾄ】ステートメントで繰り返し処理の始まりです。カウンター変数iにチェックボックスの数である1～4の値を順次代入します。

22行目【If Controls(“checkbox” & i).Value = True Then】
If【ｲﾌ】ステートメントで条件分岐です。Controls【ｺﾝﾄﾛｰﾙｽﾞ】コレクションを使用して引数にチェックボックスのオブジェクト名を設定して個々のチェックボックスオブジェクトのValue【ﾊﾞﾘｭｰ】プロパティでチェック状態を確認しTrue（チェックされている）の場合を定義します。

23行目【Worksheets(“sheet1”).Cells(最終行, i).Value = “●”】
22行目の条件分岐が成立した場合つまり、チェックボックスがチェックされている場合セルのデータが入力されている次の行のi列目に●を代入します。

24～25行目【Else
Worksheets(“sheet1”).Cells(最終行, i).Value = “×”】
Else【ｴﾙｽ】キーワードを使用して条件が成立しなかった場合、つまりチェックボックスがチェックされていない場合、セルのデータが入力されている次の行のi列目に×を代入します。