VBA ファイルの操作や取得をするFSOのメソッドやプロパティ

ファイルの操作や取得をするFSOのメソッド一覧

GetFile【ｹﾞｯﾄﾌｧｲﾙ】メソッド

ファイルをFileSystemObject【ﾌｧｲﾙｼｽﾃﾑｵﾌﾞｼﾞｪｸﾄ】（以下FSO）の「Fileオブジェクト」として取得するには、FSOオブジェクトのGetfile【ｹﾞｯﾄﾌｧｲﾙ】メソッドを使用します。File【ﾌｧｲﾙ】オブジェクトのプロパティを使用して、ファイルのさまざまな情報を取得したり、メソッドを使用してファイルの操作をすることができます。

GetFile【ｹﾞｯﾄﾌｧｲﾙ】メソッドの書式と設定値(引数)の説明

オブジェクト.GetFile(FilePath)

FileExists【ﾌｧｲﾙｲｸﾞｽﾞｨｽﾄｩ】メソッド

FSOでファイルの存在を確認するには、FSOオブジェクトのFileExists【ﾌｧｲﾙｲｸﾞｽﾞｨｽﾄｩ】メソッドを使用します。指定されたファイルが存在する場合は　「True」指定されたファイルが存在しない場合は「False」を返します。

FileExists【ﾌｧｲﾙｲｸﾞｽﾞｨｽﾄｩ】メソッドの書式と設定値(引数)の説明

オブジェクト.FileExists(FileSpec)
【戻り値】ブール型(Boolean)

DeleteFile【ﾃﾞﾘｰﾄﾌｧｲﾙ】メソッド

FSOでファイルを削除するにはFSOオブジェクトのDeleteFile【ﾃﾞﾘｰﾄﾌｧｲﾙ】メソッドを使用します。

DeleteFile【ﾃﾞﾘｰﾄﾌｧｲﾙ】メソッドの書式と設定値(引数)の説明

[]内は省略可能です。
オブジェクト.DeleteFile ( Filespec[, Force] )

InputBoxに入力されたこのブックと同じ場所にあるファイルを削除するコード例

Sub ファイル削除()
Dim FSO As New FileSystemObject
Dim ファイル名 As String
ファイル名 = InputBox("削除したいファイル名を拡張子付きで指定してください。")
If FSO.FileExists(ThisWorkbook.Path & "¥" & ファイル名) Then
FSO.DeleteFile (ThisWorkbook.Path & "¥" & ファイル名)
Else
MsgBox "ファイルは存在しません。"
Exit Sub
End If
MsgBox ファイル名 & "ファイルを削除しました。"
End Sub

CopyFile【ｺﾋﾟｰﾌｧｲﾙ】メソッド

FSOでファイルをコピーするにはFSOオブジェクトのCopyFile【ｺﾋﾟｰﾌｧｲﾙ】メソッドを使用します。

CopyFile【ｺﾋﾟｰﾌｧｲﾙ】メソッドの書式と設定値(引数)の説明

[]内は省略可能です。
オブジェクト.CopyFile( Source, Destination[, Overwrite] )

InputBoxで指定されたファイルをバックアップフォルダーにコピーするコード例

Sub ファイルコピー()
Dim FSO As New FileSystemObject
Dim ファイル名 As String
ファイル名 = InputBox("バックアップしたいファイル名を拡張子付きで指定してください。")
If FSO.FileExists(ThisWorkbook.Path & "¥" & ファイル名) Then
FSO.CopyFile Source:=ThisWorkbook.Path & "¥" & ファイル名, _
Destination:=ThisWorkbook.Path & "¥バックアップ¥" & ファイル名
Else
MsgBox "ファイルは存在しません。"
Exit Sub
End If
MsgBox ファイル名 & "ファイルをコピーしました。"
End Sub

※このブックと同じ場所に「バックアップ」ファルダーがあることが前提です。

MoveFile【ﾑｰﾌﾞﾌｧｲﾙ】メソッド

FSOでファイルを移動するには、FSOオブジェクトのMoveFile【ﾑｰﾌﾞﾌｧｲﾙ】メソッドを使用します。

MoveFile【ﾑｰﾌﾞﾌｧｲﾙ】メソッドの書式と設定値(引数)の説明

[]内は省略可能です。
オブジェクト.MoveFile( Source, Destination )

InputBoxで指定されたファイルを「処理済みフォルダー」に移動するコード例

Sub ファイル移動()
Dim FSO As New FileSystemObject
Dim ファイル名 As String
ファイル名 = InputBox("処理済みにしたいファイル名を拡張子付きで指定してください。")
If FSO.FileExists(ThisWorkbook.Path & "¥" & ファイル名) Then
FSO.MoveFile Source:=ThisWorkbook.Path & "¥" & ファイル名, _
Destination:=ThisWorkbook.Path & "¥処理済み¥" & ファイル名
Else
MsgBox "ファイルは存在しません。"
Exit Sub
End If
MsgBox ファイル名 & "ファイルを移動しました。"
End Sub

※このブックの場所に「処理済みフォルダー」があることが前提です。

GetBaseName【ｹﾞｯﾄﾍﾞｰｽﾈｰﾑ】メソッド

GetExtensionName【ｹﾞｯﾄｴｸｽﾃﾝｼｮﾝﾈｰﾑ】メソッド

FSOで指定したファイル名の拡張子を除いたファイル名を取得するには、FSOオブジェクトのGetBaseName【ｹﾞｯﾄﾍﾞｰｽﾈｰﾑ】メソッドを使用します。

FSOで指定したファイル名のファイル名を除いた拡張子を取得するには、FSOオブジェクトのGetExtensionName【ｹﾞｯﾄｴｸｽﾃﾝｼｮﾝﾈｰﾑ】メソッドを使用します。

GetBaseName・GetExtensionNameメソッドの書式と設定値(引数)の説明

オブジェクト.GetBaseName(Path)
オブジェクト.GetExtensionName(Path)

InputBoxに入力されたファイル名をファイル名と拡張子に分けて表示するコート例

Sub ファイル名分割()
Dim FSO As New FileSystemObject
Dim ファイル名 As String
Dim 拡張子 As String
ファイル名 = InputBox("ファイル名を拡張子付きで入力してください。")
拡張子 = FSO.GetExtensionName(ファイル名)
ファイル名 = FSO.GetBaseName(ファイル名)
MsgBox "ファイル名は" & ファイル名 & "です。" & vbCrLf & _
"拡張子は" & 拡張子 & "です。"
End Sub

Fileオブジェクトの主なプロパティ一覧

• Attributes【ｱﾄﾘﾋﾞｭｰﾂ】プロパティ
  ファイルの属性を取得または、設定します。
  戻り値はvbFileAttribute列挙型の定数の値で返ります。

• DateCreated【ﾃﾞｲﾄｸﾘｴｰﾃｯﾄﾞ】プロパティ
  ファイルの作成日時を取得します。
• DateLastAccessed【ﾃﾞｲﾄﾗｽﾄｱｸｾｯﾄﾞｩ】プロパティ
  最後にアクセスされた日時を取得します。
• DateLastModified【ﾃﾞｲﾄﾗｽﾄﾓｰﾃﾞｨﾌｧｲﾄﾞ】プロパティ
  最後に更新された日時を取得します。
• Drive【ﾄﾞﾗｲﾌﾞ】プロパティ
  指定したファイルが保存されているドライブを取得します。
• Name【ﾈｰﾑ】プロパティ
  ファイル名を取得または、設定します。
• ParentFolder【ﾊﾟﾚﾝﾄﾌｫﾙﾀﾞｰ】プロパティ
  指定したファイルが保存されているフォルダーを取得します。
• Path【ﾊﾟｽ】プロパティ
  ファイルのパスを取得します。
• Size【ｻｲｽﾞ】プロパティ
  ファイルの容量をバイト単位で取得します。
• Type【ﾀｲﾌﾟ】プロパティ
  ファイルの種類を表す文字列を取得します。

InputBoxで指定されたファイルの各プロパティを取得するコードと解説

Sub ファイルプロパティ()
Dim FSO As New FileSystemObject
Dim ファイル名 As String
Dim ファイル As Object
ファイル名 = InputBox("ファイル名を拡張子付きで入力してください。")
If FSO.FileExists(ファイル名) Then
 Set ファイル = FSO.GetFile(ファイル名)
Else
MsgBox "ファイルは存在しません。"
Exit Sub
End If
With ファイル
MsgBox "ファイルの属性は" & .Attributes & "です。" & vbCrLf & _
       "ファイルの作成日時は" & .DateCreated & "です。" & vbCrLf & _
       "最後にアクセスした日時は" & .DateLastAccessed & "です。" & vbCrLf & _
       "最後に更新した日時は" & .DateLastModified & "です。" & vbCrLf & _
       "ドライブは" & .Drive & "です。" & vbCrLf & _
       "ファイルの名は" & .Name & "です。" & vbCrLf & _
       "フォルダー名は" & .ParentFolder & "です。" & vbCrLf & _
       "ファイルのパスは" & .Path & "です。" & vbCrLf & _
       "ファイルのサイズは" & .Size & "バイトです。" & vbCrLf & _
       "ファイルの種類は" & .Type & "です。"
End With
End Sub

以上で、ファイルの操作や取得をするFSOのメソッドやプロパティについての解説を終了します。ありがとうございました。