VBA フォルダーの操作や取得をするFSOのメソッドやプロパティ

GetFolder【ｹﾞｯﾄﾌｫﾙﾀﾞｰ】メソッド

フォルダーをFileSystemObject【ﾌｧｲﾙｼｽﾃﾑｵﾌﾞｼﾞｪｸﾄ】（以下FSO）のFolder【ﾌｫﾙﾀﾞｰ】オブジェクトとして取得するには、GetFolder【ｹﾞｯﾄﾌｫﾙﾀﾞｰ】メソッドを使用します。Folder【ﾌｫﾙﾀﾞｰ】オブジェクトのメソッドやプロパティを使用して、ファルダーの操作や取得ができるようになります。

GetFolder【ｹﾞｯﾄﾌｫﾙﾀﾞｰ】メソッドの書式と設定値(引数)の説明

オブジェクト.GetFolder( FolderPath )

FolderExiste【ﾌｫﾙﾀﾞｰｲｸﾞｽﾞｨｽﾄｩ】メソッド

FSOでフォルダーの存在を確認するには、FolderExiste【ﾌｫﾙﾀﾞｰｲｸﾞｽﾞｨｽﾄｩ】メソッドを使用します。指定されたファイルが存在する場合は　「True」指定されたファイルが存在しない場合は「False」を返します。

FolderExiste【ﾌｫﾙﾀﾞｰｲｸﾞｽﾞｨｽﾄｩ】メソッドの書式と設定値(引数)の説明

オブジェクト.FolderExiste( FolderSpec )
【戻り値】ブール型(Boolean)

CreateFolder【ｸﾘｴｰﾄﾌｫﾙﾀﾞｰ】メソッド

FSOでフォルダーを作成するには、CreateFolder【ｸﾘｴｰﾄﾌｫﾙﾀﾞｰ】メソッドを使用します。

CreateFolder【ｸﾘｴｰﾄﾌｫﾙﾀﾞｰ】メソッドの書式と設定値(引数)の説明

オブジェクト.CreateFolder( FolderPath )

InputBoxに入力されたフォルダー名でファルダーを作成するコード例

Sub フォルダー作成()
Dim FSO As New FileSystemObject
Dim フォルダー名 As String
フォルダー名 = InputBox("作成するフォルダー名を入力してください。")
If Not FSO.FolderExists(ThisWorkbook.Path & "¥" & フォルダー名) Then
FSO.CreateFolder (ThisWorkbook.Path & "¥" & フォルダー名)
Else
MsgBox "既に同じ名前のフォルダーがあります。"
Exit Sub
End If
MsgBox ThisWorkbook.Path & "に" & フォルダー名 & "フォルダーを作成しました。"
End Sub

DeleteFolder【ﾃﾞﾘｰﾄﾌｫﾙﾀﾞｰ】メソッド

FSOでフォルダーを削除するには、DeleteFolder【ﾃﾞﾘｰﾄﾌｫﾙﾀﾞｰ】メソッドを使用します。フォルダー内に格納されているファイルも同時に削除されます。Kill【ｷﾙ】ステートメントでファイルを削除してからフォルダーを削除する必要がある
RmDir【ﾘﾑｰﾌﾞﾃﾞﾚｸﾄﾘ】ステートメントと比べて簡潔なコードで記述ができます。

DeleteFolder【ﾃﾞﾘｰﾄﾌｫﾙﾀﾞｰ】メソッドの書式と設定値(引数)の説明

[]内は省略可能です。
オブジェクト.DeleteFolder ( Folderspec[, Force] )

InputBoxに入力されたこのブックと同じ場所にあるフォルダーを削除するコード例

Sub フォルダー削除()
Dim FSO As New FileSystemObject
Dim フォルダー名 As String
フォルダー名 = InputBox("削除したいフォルダー名を入力してください。")
If FSO.FolderExists(ThisWorkbook.Path & "¥" & フォルダー名) Then
FSO.DeleteFolder (ThisWorkbook.Path & "¥" & フォルダー名)
Else
MsgBox "指定のフォルダーは存在しません。"
Exit Sub
End If
MsgBox フォルダー名 & "フォルダーを削除しました。"
End Sub

CopyFolder【ｺﾋﾟｰﾌｫﾙﾀﾞｰ】メソッド

FSOでフォルダーをコピーするには、CopyFolder【ｺﾋﾟｰﾌｫﾙﾀﾞｰ】メソッドを使用します。

CopyFolder【ｺﾋﾟｰﾌｫﾙﾀﾞｰ】メソッドの書式と設定値(引数)の説明

[]内は省略可能です。
オブジェクト.CopyFolder ( Source, Destination[, Overwrite] )

InputBoxで指定されたフォルダーをバックアップフォルダーにコピーするコード例

Sub フォルダーコピー()
Dim FSO As New FileSystemObject
Dim フォルダー名 As String
フォルダー名 = InputBox("バックアップを作成したいフォルダー名を入力してください。")
If FSO.FolderExists(ThisWorkbook.Path & "¥" & フォルダー名) Then
FSO.CopyFolder Source:=ThisWorkbook.Path & "¥" & フォルダー名, _
Destination:=ThisWorkbook.Path & "¥バックアップ¥" & フォルダー名
Else
MsgBox "指定のフォルダーは存在しません。"
Exit Sub
End If
MsgBox フォルダー名 & "フォルダーをバックアップしました。"
End Sub

※このブックの場所に「バックアップ」という名前のフォルダーがあることが前提です。
※フォルダーの中のファイルもコピーされます。

MoveFolder【ﾑｰﾌﾞﾌｫﾙﾀﾞｰ】メソッド

FSOでフォルダーをコピーするには、MoveFolder【ﾑｰﾌﾞﾌｫﾙﾀﾞｰ】メソッドを使用します。

MoveFolder【ﾑｰﾌﾞﾌｫﾙﾀﾞｰ】メソッドの書式と設定値(引数)の説明

[]内は省略可能です。
オブジェクト.MoveFolder ( Source, Destination )

InputBoxで指定されたフォルダーを「処理済みフォルダー」に移動するコード例

Sub フォルダー移動()
Dim FSO As New FileSystemObject
Dim フォルダー名 As String
フォルダー名 = InputBox("処理済みにしたいフォルダー名を拡張子付きで指定してください。")
If FSO.FolderExists(ThisWorkbook.Path & "¥" & フォルダー名) Then
FSO.MoveFolder Source:=ThisWorkbook.Path & "¥" & フォルダー名, _
Destination:=ThisWorkbook.Path & "¥処理済み¥" & フォルダー名
Else
MsgBox "フォルダーは存在しません。"
Exit Sub
End If
MsgBox フォルダー名 & "フォルダーを移動しました。"
End Sub

※このブックの場所に「処理済みフォルダー」があることが前提です。

Folder【ﾌｫﾙﾀﾞｰ】オブジェクトの主なプロパティ一覧

• Attributes【ｱﾄﾘﾋﾞｭｰﾂ】プロパティ
  フォルダーの属性を取得または、設定します。
  戻り値はvbFileAttribute列挙型の定数の値で返ります。

• DateCreated【ﾃﾞｲﾄｸﾘｴｰﾃｯﾄﾞ】プロパティ
  フォルダーの作成日時を取得します。
• DateLastAccessed【ﾃﾞｲﾄﾗｽﾄｱｸｾｯﾄﾞｩ】プロパティ
  最後にアクセスされた日時を取得します。
• DateLastModified【ﾃﾞｲﾄﾗｽﾄﾓｰﾃﾞｨﾌｧｲﾄﾞ】プロパティ
  最後に更新された日時を取得します。
• Drive【ﾄﾞﾗｲﾌﾞ】プロパティ
  指定したファイルが保存されているドライブを取得します。
• Files【ﾌｧｲﾙｽﾞ】プロパティ
  フォルダー内のすべてのファイルを取得します。
• IsRootFolder【ｲｽﾞﾙｰﾄﾌｫﾙﾀﾞｰ】プロパティ
  ルートフォルダーかどうか調べます。
• Name【ﾈｰﾑ】プロパティ
  フォルダー名を取得または、設定します。
• ParentFolder【ﾊﾟﾚﾝﾄﾌｫﾙﾀﾞｰ】プロパティ
  指定したフォルダーが保存されているフォルダーを取得します。
• Path【ﾊﾟｽ】プロパティ
  フォルダーのパスを取得します。
• Size【ｻｲｽﾞ】プロパティ
  フォルダー内のファイルおよび
  サブフォルダーの合計容量をバイト単位で取得します。
• SubFolder【ｻﾌﾞﾌｫﾙﾀﾞｰ】プロパティ
  フォルダー内のすべてのフォルダーを取得します。

InputBoxで指定されたフォルダーの各プロパティを取得するコードと解説

Sub フォルダープロパティ()
Dim FSO As New FileSystemObject
Dim フォルダー名 As String
Dim フォルダー As Object
フォルダー名 = InputBox("プロパティを取得したいフォルダー名を入力してください。")
If FSO.FolderExists(フォルダー名) Then
 Set フォルダー = FSO.GetFolder(フォルダー名)
Else
MsgBox "フォルダーは存在しません。"
Exit Sub
End If
With フォルダー
MsgBox "フォルダーの属性は" & .Attributes & "です。" & vbCrLf & _
       "フォルダーの作成日時は" & .DateCreated & "です。" & vbCrLf & _
       "最後にアクセスした日時は" & .DateLastAccessed & "です。" & vbCrLf & _
       "最後に更新した日時は" & .DateLastModified & "です。" & vbCrLf & _
       "ドライブは" & .Drive & "です。" & vbCrLf & _
       "フォルダー名は" & .Name & "です。" & vbCrLf & _
       "フォルダーのパスは" & .Path & "です。" & vbCrLf & _
       "フォルダー内のサイズは" & .Size & "バイトです。"
End With
End Sub

以上で、フォルダーの操作や取得をするFSOのメソッドやプロパティについての解説を終了します。ありがとうございました。