Excel VBA 時間のかかるマクロの進捗状況を表示する

Sub ステータス表示()
Dim i As Long
For i = 1 To 30000
Application.StatusBar = "実行中..." & Left(String(Int(i / 30000 * 10), "■") & String(10, "□"), 10)
Next i
Application.StatusBar = False
MsgBox "処理が終了しました。"
End Sub

4行目【 Application.StatusBar = “実行中…” & Left(String(Int(i / 30000 * 10), “■”) & String(10, “□”), 10) 】Application【ｱﾌﾟﾘｹｰｼｮﾝ】オブジェクトのStatusBar【ｽﾃｰﾀｽﾊﾞｰ】プロパティに表示する文字列を代入します。「□」を10個分用意して、その前で「■」の個数を変化させることにより、棒グラフが伸びるように表現しました。ここでは、Left【ﾚﾌﾄ】関数、String【ｽﾄﾘﾝｸﾞ】関数、Int【ｲﾝﾄ】関数が使用します。それぞれの関数を簡単に説明します。

• Left【ﾚﾌﾄ】関数
  文字列の左から文字数分の文字列を抜き出す関数です。
  書式はLeft(文字列,文字数）
• String【ｽﾄﾘﾝｸﾞ】関数
  指定した文字を指定数表示する関数です。
  書式はString(表示する数,表示する文字）
• Int【ｲﾝﾄ】関数
  引数に入れた数値または数式の小数点以下を除いた整数を返す関数です。
  書式はInt(小数点型数値または数式）

【 Left(String(Int(i / 30000 * 10), “■”) & String(10, “□”), 10) 】
まずは、Left関数の引数から見ていきます。Int関数で変数（i÷30000×10個）で繰り返し処理の進捗割合を計算して整数にします。String関数で「■」を繰り返しの進捗割合の数表示する設定にします。ここでの計算は例えば繰り返し回数のカウンタ―変数(i)が最後の繰り返し30000だった場合（30000÷30000*10)で10になります。29999回だった場合は
（29999÷30000*10)で9.999・・となりますが、Int関数は整数部分だけ返す関数なので9となります。

次のString関数では「□」を10個表示する設定にして「&」(ｱﾝﾊﾟｻﾝﾄﾞ)で連結しています。
繰り返し回数が増える毎に、「■」の数が増えていき10個表示されている「□」が右にズレていきます。それをLeft関数で表示を左から10文字に指定しているので「□」が「■」に変化しているように見えるわけです。

6行目【 Application.StatusBar = False 】
Application【ｱﾌﾟﾛｹｰｼｮﾝ】オブジェクトのStatusBar【ｽﾃｰﾀｽﾊﾞｰ】プロパティにFalse【ﾌｫｰﾙｽ】を設定してステータスバーの表示を非表示にします。

7行目【 MsgBox “処理が終了しました。” 】
MsgBox関数を使用して処理が終了したことを伝えます。

Private Sub UserForm_Initialize()
With ProgressBar1
    .Min = 0
    .Max = 30000
    .Value = 0
End With
パーセント.Caption = ""
End Sub

2.ダウンリストの中から「UserForm」を選択します。

3.右のダウンリストから「Initialize」を選択します。
してコードを記述します。

2行目【 With ProgressBar1 】
With【ｳｨｽﾞ】ステートメントで 「ProgressBar1」【プログレスバー1】を指定します。

3行目【 .Min = 0 】
With【ｳｨｽﾞ】ステートメントで指定したProgressBar1【プログレスバー1】の最小値を設定するMin【ﾐﾆ】プロパティに0に設定します。

4行目【 .Max = 30000 】
With【ｳｨｽﾞ】ステートメントで指定したProgressBar1【プログレスバー1】の最大値を設定するMax【ﾏｯｸｽ】プロパティに30000に設定します。

5行目【 .Value = 0 】
With【ｳｨｽﾞ】ステートメントで指定したProgressBar1【プログレスバー1】の初期の表示値を設定するValue【ﾊﾞﾘｭｰ】プロパティに0を設定します。

7行目【 パーセント.Caption = “” 】

進捗のパーセントを表示するLabel【ﾗﾍﾞﾙ】オブジェクトの「パーセント」の表示する文字を表すCaption【ｷｬﾌﾟｼｮﾝ】プロパティに「長さ0文字の文字列」を指定して、空白を表示します。

Sub info表示()
Dim i As Long
info.Show vbModeless
For i = 1 To 30000
With info
     .ProgressBar1.Value = i
     .パーセント.Caption = Int(i / 30000 * 100) & "%"
     .Repaint
End With
Next i
info.Hide
MsgBox "処理が終了しました。"
Unload info
End Sub

6行目【 .ProgressBar1.Value = i 】
With【ｳｨｽﾞ】ステートメントで指定したユーザーフォームオブジェクトのProgressBar1【プログラスバー1】オブジェクトのValue【ﾊﾞﾘｭｰ】プロパティにカウンター変数「i」を設定して
値を増加させていきます。

7行目【 .パーセント.Caption = Int(i / 30000 * 100) & “%” 】
With【ｳｨｽﾞ】ステートメントで指定したユーザーフォームオブジェクトのLabel【ﾗﾍﾞﾙ】オブジェクトの「パーセント」の表示を表すCaption【ｷｬﾌﾟｼｮﾝ】プロパティに進捗の割合を表示します。

8行目【 .Repaint 】
ユーザーフォームオブジェクトのRepaint【ﾘﾊﾟｲﾝﾄ】メソッドを使用してユーザーフォームに画面の更新がある場合に画面の再描画を実行します。ここまでを繰り返し処理の中に記述します。

11行目【 info.Hide 】
繰り返し処理の直後にHide【ﾋﾃﾞﾝ】メソッドを使用して一旦、ユーザーフォームの表示を非表示にします。

12行目【 MsgBox “処理が終了しました。” 】
MsgBox【ﾒｯｾｰｼﾞﾌﾞｯｸｽ】関数を使用して、ユーザーに処理が終わったことを伝えます。

13行目【 Unload info　】
ユーザーフォームを閉じます。