セルに罫線【けいせん】を設定する方法
VBAで罫線を扱うには、Border【ﾎﾞｰﾀﾞｰ】オブジェクトが持つ各種のプロパティで線のスタイルや太さ、色などを設定します。
また、Range【ﾚﾝｼﾞ】オブジェクトのBorderaround【ﾎﾞﾀﾞｰｱﾗｳﾝﾄﾞ】メソッドを使用すると
セル範囲の外枠の線の種類や太さ、色を一度に設定できます。
Borders【ﾎﾞｰﾀﾞｰｽﾞ】プロパティ
セルの上下左右、斜めに設定されている罫線を表すBorder【ﾎﾞｰﾀﾞｰ】オブジェクトを取得するには、Range【ﾚﾝｼﾞ】オブジェクトのBorders【ﾎﾞｰﾀﾞｰｽﾞ】プロパティを使用します。
Border【ﾎﾞｰﾀﾞｰ】オブジェクトを取得するには、Borders【ﾎﾞｰﾀﾞｰｽﾞ】プロパティで対象となる罫線の位置を引数で参照する必要があります。Borders【ﾎﾞｰﾀﾞｰｽﾞ】プロパティで引数を省略した場合は、すべての罫線を表すBorders【ﾎﾞｰﾀﾞｰｽﾞ】コレクションが取得されます。
Borders【ﾎﾞｰﾀﾞｰｽﾞ】プロパティの書式と設定値(引数)の説明
[]内は省略可能です。
オブジェクト.Borders( [Index] )
- オブジェクト（必須）
罫線を設定するセル、またはセル範囲をRange【ﾚﾝｼﾞ】オブジェクトを指定します。 - Index【ｲﾝﾃﾞｯｸｽ】（省略可）
参照する罫線の位置をxlBordersIndex列挙型の定数、または値で指定します。
| 定数 | 値 | 内容 |
|---|---|---|
| xlEdgeTop【ｴｯｼﾞﾄｯﾌﾟ】 | 8 | 上端の横線 |
| xlEdgeBottom【ｴｯｼﾞﾎﾞﾄﾑ】 | 9 | 下端の横線 |
| xlEdgeLeft【ｴｯｼﾞﾚﾌﾄ】 | 7 | 左端の縦線 |
| xlEdgeRight【ｴｯｼﾞﾗｲﾄ】 | 10 | 右端の縦線 |
| xlInsideHorizontal【ｲﾝｻｲﾄﾞﾎﾘｿﾞﾝﾀﾙ】 | 12 | 選択範囲内の内側の水平（横）線 |
| xlInsideVertical【ｲﾝｻｲﾄﾞﾊﾞｰﾃｨｶﾙ】 | 11 | 選択範囲内の内側の垂直（縦）線 |
| xlDiagonalDown【ﾀﾞｲｱｺﾞﾅﾙﾀﾞｳﾝ】 | 5 | 各セルの左上隅から右下への罫線 |
| xlDiagonalUp【ﾀﾞｲｱｺﾞﾅﾙｱｯﾌﾟ】 | 6 | 各セルの左下隅から右上への罫線 |
※右下がりの斜線と右上がりの斜線は、単一セルが対象です。複数のセルを選択した場合は、それぞれのセルに斜線が引かれます。複数のセルをまたがって斜線を引く場合はShape（図形）の直線を使用します。
罫線を設定するBorderオブジェクトのプロパティ一覧
| プロパティ | 内容 |
|---|---|
| LineStyle【ﾗｲﾝｽﾀｲﾙ】 | 罫線の種類を設定します。種類は8種類あります。 |
| Weight【ｳｴｲﾄ】 | 罫線の太さを設定します。種類は4種類あります。 |
| Color【ｶﾗｰ】 ColorIndex【ｶﾗｰｲﾝﾃﾞｯｸｽ】 | 罫線に色を設定します。 |
LineStyle【ﾗｲﾝｽﾀｲﾙ】プロパティ
罫線の種類を設定するには、Border【ﾎﾞｰﾀﾞｰ】オブジェクトのLineStyle【ﾗｲﾝｽﾀｲﾙ】プロパティを使用します。値の取得と設定ができます。
LineStyle【ﾗｲﾝｽﾀｲﾙ】プロパティの書式と設定値の説明
オブジェクト.LineStyle = 設定値
- オブジェクト（必須）
Border【ﾎﾞｰﾀﾞｰ】オブジェクトまたは、Borders【ﾎﾞｰﾀﾞｰｽﾞ】コレクションを指定します。 - 設定値（必須）
罫線の種類をxlLineStyle列挙型の定数で指定します。オブジェクトがBordes【ﾎﾞｰﾀﾞｰｽﾞ】コレクションの場合は選択範囲のセルの4辺が対象になります。
| 定数 | 値 | 内容 |
|---|---|---|
| xlContinuous【ｺﾝﾃｭﾆｱｽ】 または、True | 1 | 実線 |
| xlDash【ﾀﾞｯｼｭ】 | -4115 | 破線 |
| xlDashDot【ﾀﾞｯｼｭﾄﾞｯﾄ】 | 4 | 一点鎖線 |
| xlDashDotDot【ﾀﾞｯｼｭﾄﾞｯﾄﾄﾞｯﾄ】 | 5 | ニ点鎖線 |
| xlDot【ﾄﾞｯﾄ】 | -4118 | 点線 |
| xlDouble【ﾀﾞﾌﾞﾙ】 | -4119 | 二重線 |
| xlSlantDashDot【ｽﾗﾝﾄﾀﾞｯｼｭﾄﾞｯﾄ】 | 13 | 斜め破線 |
| xlLineStyleNone【ﾗｲﾝｽﾀｲﾙﾅﾑ】 または、False | -4142 | 線なし |
指定したセル4辺に罫線を設定するコード例
Sub 罫線()
Range("B2").Value = "実線"
Range("B2").Borders.LineStyle = True
Range("B4").Value = "破線"
Range("B4").Borders.LineStyle = xlDash
Range("B6").Value = "一点鎖線"
Range("B6").Borders.LineStyle = xlDashDot
Range("B8").Value = "二点鎖線"
Range("B8").Borders.LineStyle = xlDashDotDot
Range("B10").Value = "点線"
Range("B10").Borders.LineStyle = xlDot
Range("B12").Value = "二重線"
Range("B12").Borders.LineStyle = xlDouble
Range("B14").Value = "斜め破線"
Range("B14").Borders.LineStyle = xlSlantDashDot
Range("B16").Value = "線なし"
Range("B16").Borders.LineStyle = False
End Sub
実行結果
Weight【ｳｴｲﾄ】プロパティ
罫線の太さを設定するには、Border【ﾎﾞｰﾀﾞｰ】オブジェクトのWeight【ｳｴｲﾄ】プロパティを使用します。
Weight【ｳｴｲﾄ】プロパティの書式と設定値の説明
オブジェクト.Weight = 設定値
- オブジェクト（必須）
Border【ﾎﾞｰﾀﾞｰ】オブジェクトまたは、Borders【ﾎﾞﾀﾞｰｽﾞ】コレクションを指定します。 - 設定値（必須）
罫線の太さをxlBorderWeight列挙型の定数で指定します。
| 定数 | 値 | 内容 |
|---|---|---|
| xlHairline【ﾍｱﾗｲﾝ】 | 1 | 極細線 |
| xlThin【ｽｲﾝ】 | 2 | 細線（既定値） |
| xlMedium【ﾐﾃﾞｨｱﾑ】 | -4138 | 中線 |
| xlThick【ｼｯｸ】 | 4 | 太線 |
実線の太さを変更するコード例
Sub 罫線太さ()
Range("B2").Value = "極細線"
With Range("B2").Borders(xlEdgeTop)
.LineStyle = xlContinuous
.Weight = xlHairline
End With
Range("B3").Value = "細線"
With Range("B3").Borders(xlEdgeTop)
.LineStyle = xlContinuous
.Weight = xlThin
End With
Range("B4").Value = "中線"
With Range("B4").Borders(xlEdgeTop)
.LineStyle = xlContinuous
.Weight = xlMedium
End With
Range("B5").Value = "太線"
With Range("B5").Borders(xlEdgeTop)
.LineStyle = xlContinuous
.Weight = xlThick
End With
End Sub
実行結果
※線の種類と太さの組み合わせにより、一方の設定が無効になる場合があります。設定できる組み合わせは、「セルの書式設定」ダイアログボックスの「罫線」タブの「線」「スタイル」リストにある組み合わせになります。
Color【ｶﾗｰ】ColorIndex【ｶﾗｰｲﾝﾃﾞｯｸｽ】プロパティ
罫線に色を設定するには、Border【ﾎﾞｰﾀﾞｰ】オブジェクトのColor【ｶﾗｰ】プロパティまたは、ColorIndex【ｶﾗｰｲﾝﾃﾞｯｸｽ】プロパティを使用します。値の取得と設定ができます。
Color、ColorIndex、プロパティの書式と設定値の説明
オブジェクト.Color = RGB値
オブジェクト.ColorIndex = カラー番号
B2セルを赤い太線で囲むコード例
Sub 線色()
With Range("B2").Borders
.LineStyle = True
.Weight = xlThick
.Color = RGB(255, 0, 0)
End With
End Sub
実行結果
BorderAround【ﾎﾞﾀﾞｰｱﾗｳﾝﾄﾞ】メソッド
セル範囲の周囲（外枠）に線の種類や太さ、色を一度に指定して罫線を引くには、Range【ﾚﾝｼﾞ】オブジェクトのBorderAround【ﾎﾞﾀﾞｰｱﾗｳﾝﾄﾞ】メソッドを使用します。
BorderAround【ﾎﾞﾀﾞｰｱﾗｳﾝﾄﾞ】メソッドの書式と設定値の説明
[]内は省略可能です。
オブジェクト.BorderAround( [LineStyle, Weight, ColorIndex, Color] )
- オブジェクト（必須）
外枠の線を設定するセルやセル範囲をRange【ﾚﾝｼﾞ】オブジェクトで指定します。 - LineStyle【ﾗｲﾝｽﾀｲﾙ】（省略可）
線の種類をxlBoderStyle列挙型の定数で指定します。 - Weight【ｳｴｲﾄ】（省略可）
線の太さをxlBorderWeight列挙型の定数で指定します。 - ColorIndex【ｶﾗｰｲﾝﾃﾞｯｸｽ】（省略可）
線の色をxlColorIndex列挙型の定数または、56色カラーパレットの番号を指定します。
引数Colorと同時に設定することはできません。 - Color【ｶﾗｰ】（省略可）
線の色をRGB関数で指定します。引数ColorIndexと同時に指定することはできません。
B2セルから始まる表範囲に罫線と外枠に赤の2重罫線B2セルに斜線を引くコード例
Sub 表範囲罫線()
With Range("B2").CurrentRegion
.Borders.LineStyle = True
.BorderAround LineStyle:=xlDouble, Color:=RGB(255, 0, 0)
End With
Range("B2").Borders(xlDiagonalDown).LineStyle = True
End Sub
実行前
実行後
罫線を消去する方法
罫線を消去するには、LineStyle【ﾗｲﾝｽﾀｲﾙ】プロパティにxlLinestyleNoneまたはFalseを指定します。例えば、アクティブシートのすべての罫線を消去する場合は【 Cells.Borders.LineStyle = False 】と記述します。
このコードでは斜線は消去されないため斜線を消去するには
【 Cells.Borders(xlDiagonalDown).LineStyle = False 】
【 Cells.Borders(xlDiagonalUp).LineStyle = False 】
を別途記述する必要があります。
上記の表範囲の罫線をすべて消去するコード例
Sub 罫線削除()
Range("B2").CurrentRegion.Borders.LineStyle = False
Range("B2").Borders(xlDiagonalDown).LineStyle = False
End Sub
実行結果
以上で、セルに罫線を設定するについての解説を終了します。ありがとうございました。